Güvenli IoT İletişimi

#include <SoftwareSerial.h>
SoftwareSerial mySerial(11, 10); /* RX, TX */

#include <TanV1Seri.h>
/* Önemli.! Lütfen Değişken Adını Değiştirmeyin. */
TanV1Seri _tanV1Seri; 

void setup() {
  Serial.begin(9600);
  mySerial.begin(9600);
  while (!Serial) {
    ;
  }
  /* Donanımsal Serial nesnesi bağlanabilir... */
  /*  _tanV1Seri.basla(&Serial); */

  /* softSerial nesnesi bağlanabilir... */
  _tanV1Seri.basla(&mySerial);

  /* modül ile iletişim için */
  /* zaman aşımı süresi  */
  /* 2 saniye olarak ayarlanıyor */
  /* Bu süre içerisinde modül cevap vermezse, */
  /* Zaman aşımı değeri gönderiyor... */
  
  _tanV1Seri.bekleme(2000); 
  
  sifrele();
}
void sifrele() {
  /* şifreleme işlemi için geri dönen cevap değeri */
  byte islemCevap=0; 
  
  /* Önemli.! Bu uzunluğu değiştirmeyin.! */
  /* Şifrelenen metin 128 karakter uzunluğunda olacaktır. */
  char sifreliMetin[128]={'\0'}; 
  
  char ornekCharDizi[32]="012345678901234567890123456789";

  /* zaman aşımı olursa tekrar deniyor... */
  /* işlem tamamlanınca */
  /* veya  */
  /* paket uzun ise çıkış yapıyor... */
  while(islemCevap!=TanV1_Durum_Tamam && islemCevap!=TanV1_Durum_PaketUzun){ 
    islemCevap=_tanV1Seri.sifrele(
      ornekCharDizi, /* Şifrelenecek char dizi içeriği */
      sizeof(ornekCharDizi), /* Şifrelenecek char dizi uzunluğu */
      sifreliMetin, /* Şifrelenen char dizi içeriği*/
      TanV1_ZamanAsimi_Dakika,
      /*
        TanV1_ZamanAsimi_Yok
        TanV1_ZamanAsimi_Dakika
        TanV1_ZamanAsimi_Saat
        TanV1_ZamanAsimi_Gun
        TanV1_ZamanAsimi_Ay
        TanV1_ZamanAsimi_Yil
      */
      5 
      /* 
        istenen zaman aşımı süresi,
        oluşturulan şifre bu süre sonunda geçersiz olacaktır.
      */
    );
    if(islemCevap==TanV1_Durum_ZamanAsimi){
      Serial.println(F("Durum : (char) - Zaman Asimi"));
    }
  }
  
  if(islemCevap==TanV1_Durum_Tamam){ 
  
    /* şifrelenmiş veri oluşturuldu. */
    Serial.println(F("Durum : (char) - Sifrelendi"));
    Serial.print(F("Sifreli metin : "));
    for(byte a=0;a<128;a++){
      Serial.print(sifreliMetin[a]);
    }
    Serial.println();

    islemCevap=_tanV1Seri.coz(
      sifreliMetin, /* Şifreli char dizi içeriği*/
      ornekCharDizi, /* Çözülünce aktarılacak char dizi içeriği */
      sizeof(ornekCharDizi) /* çözülecek char dizi uzunluğu */
    );

    if(islemCevap==TanV1_Durum_Tamam){ 
      /* şifre çözme işlemi tamamlandı */ 
      Serial.println(F("Durum : (char) - Sifre Cozuldu"));
      Serial.print(F("Cozulen Dizi : "));
      for(byte a=0; a<sizeof(ornekCharDizi); a++){
        Serial.print(ornekCharDizi[a]);
      }
      Serial.println();
    }else if(islemCevap==TanV1_Durum_ZamanAsimi){ 
      /* şifre çözme işlemi zaman aşımına uğradı */
      Serial.println(F("Durum : (char) - Cozme Asamasi : Zaman Asimi"));
    }else if(islemCevap==TanV1_Durum_PaketUzun){ 
      /* çözme için gönderilen paket uzun, */ 
      Serial.println(F("Durum : (char) - Cozme Asamasi : Paket Uzun"));
    }
	
  }else if(islemCevap==TanV1_Durum_ZamanAsimi){ 
    /* şifreleme işlemi zaman aşımına uğradı */ 
    Serial.println(F("Durum : (char) - Sifreleme Asamasi : Zaman Asimi"));
  }else if(islemCevap==TanV1_Durum_PaketUzun){ 
    /* şifreleme için gönderilen paket uzun */ 
    Serial.println(F("Durum : (char) - Sifreleme Asamasi : Paket Uzun"));
  }
  
}

void loop() {

}